[Creat0R]

Погуглив так и не нашёл ответа или примера »

поиск папки autoit

А также есть уже тема на форуме.

[TERMINAL]

Creat0R, Как бы нашёл скрипт

читать дальше »

Global $Stack[50], $Stack1[50]

$Text = ""
FileFindNextFirst("C:\WINDOWS")
While 1
$tempname = FileFindNext('',2,2)
If $tempname = "" Then ExitLoop
$Text &= $tempname & @CRLF
WEnd

FileFindNextFirst("C:\WINDOWS")
While 1
$tempname = FileFindNext('',0,1)
If $tempname = "" Then ExitLoop
$Text &= $tempname & @CRLF
WEnd

MsgBox(4096, '', $Text)

Func FileFindNextFirst($FindCat)
$Stack[0] = 1
$Stack1[1] = $FindCat
$Stack[1] = FileFindFirstFile($FindCat & "\*.*")
Return $Stack[1]
EndFunc ;==>FileFindNextFirst

;$mode=0 - файлы
;$mode=1 - типы файлов
;$mode=2 - каталоги
;$Level= от 1 до 49
Func FileFindNext($type = 'log', $mode = 0, $Level=49)
While 1
$file = FileFindNextFile($Stack[$Stack[0]])
If @error Then
FileClose($Stack[$Stack[0]])
If $Stack[0] = 1 Then
Return ""
Else
$Stack[0] -= 1
ContinueLoop
EndIf
Else
If StringInStr(FileGetAttrib($Stack1[$Stack[0]] & "\" & $file), "D") > 0 Then
If $Stack[0] = $Level Then ContinueLoop
$Stack[0] += 1
$Stack1[$Stack[0]] = $Stack1[$Stack[0] - 1] & "\" & $file
$Stack[$Stack[0]] = FileFindFirstFile($Stack1[$Stack[0]] & "\*.*")
If $mode=2 Then
Return $Stack1[$Stack[0]]
Else
ContinueLoop
EndIf
Else
If $mode=2 Then ContinueLoop
If $mode=1 Then
If StringRight($Stack1[$Stack[0]] & "\" & $file, 4)<>'.'&$type Then
ContinueLoop
Else
Return $Stack1[$Stack[0]] & "\" & $file
EndIf
Else
Return $Stack1[$Stack[0]] & "\" & $file
EndIf
EndIf
EndIf
WEnd
EndFunc ;==>FileFindNext

можно переделать и будет поиск каталогов, но не могу добиться глубины поиска папок в каталоге.

[Creat0R]

нашёл скрипт »

Который нужно заключать в тег кода.

не могу добиться глубины поиска папок в каталоге »

А по ссылке перейти не судьба?

[TERMINAL]

Creat0R, Судьбу испытывал и переходил по ссылке, но там же опять поиск файлов, мне файлы не нужны-нужны сами папки

PHP код:

#include <Array.au3>



$aReturn = _FileSearch(@WindowsDir, "File\....$", 0)



_ArrayDisplay($aReturn)



Func _FileSearch($sPath, $sRegExp_FileMask, $iCaseSense=0)

    Local $iPID, $sStdOutRead, $aRet, $sFindStr, $sCaseStr



    If Not $iCaseSense Then $sCaseStr = ' /I'

    $sFindStr = 'Dir "' & $sPath & '" /S /B | FindStr' & $sCaseStr & ' /R "' & $sRegExp_FileMask & '"'



    $iPID = Run(@ComSpec & ' /C ' & $sFindStr, @SystemDir, @SW_HIDE, 2)



    While 1

        $sStdOutRead &= StdoutRead($iPID)

        If @error <> 0 Then ExitLoop

    WEnd



    $aRet = StringSplit(StringStripCR(StringStripWS($sStdOutRead, 3)), @LF)

    Return SetError(@error, 0, $aRet)

EndFunc 

Реализовать поиск папок я так и не смог.

[Creat0R]

там же опять поиск файлов, мне файлы не нужны-нужны сами папки »

Там и поиск папок:

Код:

$aReturn = _FileSearch('C:\Test', "\\5DEL$", 0)
_ArrayDisplay($aReturn)

Ещё вот тут есть более новая версия данного метода:

Код:

#include <Array.au3>

$aReturn = _FileDirList('C:\Test', "5DEL", 2)
_ArrayDisplay($aReturn)

Func _FileDirList($sPath, $sFileMask = "*", $iFlag = 0, $iSubDir = 1, $iSort = 0)
    Local $sOutBin, $sOut, $aOut, $aMasks, $sRead, $hDir, $sAttrib, $sFiles

    If Not StringInStr(FileGetAttrib($sPath), "D") Then
        Return SetError(1, 0, 0)
    EndIf

    If $iSubDir = 1 Then
        $sAttrib &= ' /S'
    EndIf

    If $iSort = 1 Then
        $sAttrib &= ' /O:N'
    EndIf

    Switch $iFlag
        Case 1
            $sAttrib &= ' /A-D'
        Case 2
            $sAttrib &= ' /AD'
        Case Else
            $sAttrib &= ' /A'
    EndSwitch

    $sOut = StringToBinary('0' & @CRLF, 2)
    $sPath = StringRegExpReplace($sPath, '\\+$', '')
    $sFileMask = StringRegExpReplace($sFileMask, '^;+|;+$', '')
    $sFileMask = StringRegExpReplace($sFileMask, ';{2,}', ';')
    $aMasks = StringSplit($sFileMask, ';')

    For $i = 1 To $aMasks[0]
        If StringStripWS($aMasks[$i], 8) = "" Then
            ContinueLoop
        EndIf

        $sFiles &= '"' & $sPath & '\' & $aMasks[$i] & '"'

        If $i < $aMasks[0] Then
            $sFiles &= ';'
        EndIf
    Next

    $hDir = Run(@ComSpec & ' /U /C DIR ' & $sFiles & ' /B' & $sAttrib, @SystemDir, @SW_HIDE, 6)

    While ProcessExists($hDir)
        $sRead = StdoutRead($hDir, False, True)

        If @error Then
            ExitLoop
        EndIf

        If $sRead <> "" Then
            $sOut &= $sRead
        EndIf
    Wend

    $aOut = StringRegExp(BinaryToString($sOut, 2), '[^\r\n]+', 3)

    If @error Or UBound($aOut) < 2 Then
        Return SetError(2, 0, 0)
    EndIf

    $aOut[0] = UBound($aOut)-1
    Return $aOut
EndFunc

[-TRM-]

Creat0R, А как-то возможно на диске найти пустые каталоги или подкаталоги и удалить их?
И такой ещё вопросик- если известен путь С:\TEST02\Downloads\TMP\VIA\FORCED\5x86\new\viamraid64.cat
то как возможно получить из него путь С:\TEST02\Downloads\TMP\VIA\FORCED\5x86\new ? (т.е. без самого файла)

[madmasles]

А как-то возможно на диске найти пустые каталоги или подкаталоги и удалить их? »

Попробуйте примерно так.

Код:

#include <Array.au3>
#include <WinAPIEx.au3>

Global $aRet, $iSuccess = 0, $iError = 0

$aRet = _FileDirList(@HomeDrive, '*', 2)
_ArrayDisplay($aRet)
For $i = 1 To $aRet[0]
    If _WinAPI_PathIsDirectoryEmpty($aRet[$i]) Then
        If DirRemove($aRet[$i]) Then
            $iSuccess += 1
        Else
            $iError += 1
        EndIf
    EndIf
Next

MsgBox(64, 'Info', StringFormat('All:\t%i\nDel:\t%i\nError:\t%i', $aRet[0], $iSuccess, $iError))

Func _FileDirList($sPath, $sFileMask = "*", $iFlag = 0, $iSubDir = 1, $iSort = 0)
    Local $sOutBin, $sOut, $aOut, $aMasks, $sRead, $hDir, $sAttrib, $sFiles

    If Not StringInStr(FileGetAttrib($sPath), "D") Then
        Return SetError(1, 0, 0)
    EndIf

    If $iSubDir = 1 Then
        $sAttrib &= ' /S'
    EndIf

    If $iSort = 1 Then
        $sAttrib &= ' /O:N'
    EndIf

    Switch $iFlag
        Case 1
            $sAttrib &= ' /A-D'
        Case 2
            $sAttrib &= ' /AD'
        Case Else
            $sAttrib &= ' /A'
    EndSwitch

    $sOut = StringToBinary('0' & @CRLF, 2)
    $sPath = StringRegExpReplace($sPath, '\\+$', '')
    $sFileMask = StringRegExpReplace($sFileMask, '^;+|;+$', '')
    $sFileMask = StringRegExpReplace($sFileMask, ';{2,}', ';')
    $aMasks = StringSplit($sFileMask, ';')

    For $i = 1 To $aMasks[0]
        If StringStripWS($aMasks[$i], 8) = "" Then
            ContinueLoop
        EndIf

        $sFiles &= '"' & $sPath & '\' & $aMasks[$i] & '"'

        If $i < $aMasks[0] Then
            $sFiles &= ';'
        EndIf
    Next

    $hDir = Run(@ComSpec & ' /U /C DIR ' & $sFiles & ' /B' & $sAttrib, @SystemDir, @SW_HIDE, 6)

    While ProcessExists($hDir)
        $sRead = StdoutRead($hDir, False, True)

        If @error Then
            ExitLoop
        EndIf

        If $sRead <> "" Then
            $sOut &= $sRead
        EndIf
    WEnd

    $aOut = StringRegExp(BinaryToString($sOut, 2), '[^\r\n]+', 3)

    If @error Or UBound($aOut) < 2 Then
        Return SetError(2, 0, 0)
    EndIf

    $aOut[0] = UBound($aOut) - 1
    Return $aOut
EndFunc   ;==>_FileDirList

WinAPIEx.au3

[AZJIO]

-TRM-,
_FO_SearchEmptyFolders

(т.е. без самого файла) »

_FO_PathSplit или регулярное выражение

Код:

StringRegExpReplace($sPath, '^(.*)\\.*$', '\1')

[madmasles]

как возможно получить из него путь С:\TEST02\Downloads\TMP\VIA\FORCED\5x86\new ? (т.е. без самого файла) »

Или так.

Код:

$sPath = @ScriptFullPath
ConsoleWrite($sPath & @LF)
ConsoleWrite(StringRegExpReplace($sPath, '\\[^\\]*$', '') & @LF)

Взято отсюда: Деление пути к файлу на части